@ECHO OFF
REM echo.
REM echo.%DATE:~3% %TIME:~0,8%

SETLOCAL ENABLEEXTENSIONS
SETLOCAL ENABLEDELAYEDEXPANSION

SET filein=%1

rem Maak folder met datum van vandaag en een temp-folder
if [%mydate%]==[] call .\getDate.bat
IF NOT EXIST %mydate% mkdir %mydate%
IF NOT EXIST temp mkdir temp

rem Deel exportbestand op in een bestand per company. Company = kolom B.
rem De buitenste for-lus zet elke kolom in "", om te zorgen dat lege kolommen niet worden overgeslagen
rem De binnenste for-lus zoekt de regels van iedere company bij elkaar en schrijft deze weg in
rem bestand temp\<company>.csv
FOR /F "usebackq skip=1 tokens=1-13 delims=" %%A in (%filein%) DO (
   SET "line=%%A"
   SETLOCAL ENABLEDELAYEDEXPANSION
   SET "line="!line:;=";"!""
   FOR /F "tokens=1-13 delims=;" %%A in ("!line!") DO (
      @echo %%~A;%%~B;%%~C;%%~D;%%~E;%%~F;%%~G;%%~H;%%~I;%%~J;%%~K;%%~L;%%~M
   ) >> temp\%%~B.csv
   ENDLOCAL
)

rem De bestanden bevatten geen header meer; er weer voor plakken.
rem Bestanden wegschrijven in <datum>\<company>.csv
FOR %%f IN (temp\*.csv) DO (
   copy /b /y ..\splitter\header.txt+temp\%%~nxf %mydate%\%%~nxf > nul
)

del /q temp\*.*
rmdir temp

echo.Splitsen voltooid; bestanden geplaatst in folder '%mydate%'.

ENDLOCAL