<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:msxml="urn:schemas-microsoft-com:xslt" version="1.0">

  <xsl:template match="factuur" mode="fininf">
    <table border="0" cellpadding="1">
      <tr>
        <td colspan="4" >
        Geachte heer/mevrouw,<br/><br/>
        Er zijn facturen in FACILITOR geregistreerd waar uw goedkeuring voor nodig is.><br/>
        Aan u het verzoek deze facturen spoedig te beoordelen en verder af te handelen in FACILITOR.<br/><br/>
        Bij voorbaat dank.
            </td>
      </tr>
            </table>
  </xsl:template>

	<xsl:template match="opdracht" mode="include">
	<xsl:variable name="opdrtype">
		<xsl:choose>
			<xsl:when test="opdrachttype/key=5">contract</xsl:when>
			<xsl:when test="opdrachttype/key=701">intern</xsl:when>
			<xsl:when test="opdrachttype/key=702">opdracht</xsl:when>
			<xsl:when test="opdrachttype/key=721">offerte</xsl:when>
			<xsl:when test="opdrachttype/key=801 or opdrachttype/key=841">klacht</xsl:when>
		</xsl:choose>
	</xsl:variable>	
		<table border="0" width="100%" cellpadding="2">
			<tr>
				<td colspan="4" class="caption" style="padding-top:20px;padding-bottom:20px">
					<b>
						<xsl:choose>
							<xsl:when test="$opdrtype='contract'">Opdracht volgens contract</xsl:when>
							<xsl:when test="$opdrtype='intern'">Interne opdracht</xsl:when>
							<xsl:when test="$opdrtype='opdracht'">Opdracht</xsl:when>
							<xsl:when test="$opdrtype='offerte'">Offerteaanvraag</xsl:when>
							<xsl:when test="$opdrtype='klacht'">Klachtmelding</xsl:when>
						</xsl:choose>&#xA0;
						<xsl:value-of select="//facilitor/header/custId"/>&#xA0;
						<xsl:value-of select="melding/stdmelding/discipline/srtdiscipline/prefix"/>
						<xsl:value-of select="melding/key"/>/<xsl:value-of select="bedrijfopdr_volgnr"/></b>
				</td>
			</tr>
			<xsl:if test="$opdrtype!='intern'">
			<tr>
				<td width="16%"/>
				<td width="34%"/>
				<td width="16%" align="right">
					<b>
						<xsl:value-of select="//lcl/FAC/bedrijf"/>:</b>
				</td>
				<td width="34%">
					<xsl:value-of select="uitvoerende/bedrijf/naam"/>
				</td>
			</tr>
			</xsl:if>
			<xsl:if test="$opdrtype='offerte' or $opdrtype='opdracht' or $opdrtype='klacht'">
			<tr>
				<td colspan="2"/>
				<td align="right">
					<b>
						<xsl:value-of select="//lcl/FAC/contactpersoon"/>:</b>
				</td>
				<td>
					<xsl:value-of select="contactpersoon/naam_full"/>
				</td>
			</tr>
			<tr>
				<td colspan="2"/>
				<td align="right">
					<b>
						<xsl:value-of select="//lcl/FAC/telefoon"/>:</b>
				</td>
				<td>
					<xsl:value-of select="contactpersoon/telefoon1"/>
				</td>
			</tr>
			<tr>
				<td colspan="2"/>
				<td align="right">
					<b>
						<xsl:value-of select="//lcl/FAC/adres"/>:</b>
				</td>
				<td>
					<xsl:value-of select="uitvoerende/bedrijf/post_adres"/>
				</td>
			</tr>
			<tr>
				<td colspan="2"/>
				<td align="right">
					<b>
						<xsl:value-of select="//lcl/FAC/plaats"/>:</b>
				</td>
				<td>
					<xsl:value-of select="uitvoerende/bedrijf/post_plaats"/>
				</td>
			</tr>
            </xsl:if>
			<tr>
				<td colspan="4">
					<hr/>
				</td>
			</tr>
			<tr>
				<td align="right" width="16%">
				<xsl:choose>
				  <xsl:when test="$opdrtype='klacht'">
				    <b>Melder:</b>
				  </xsl:when>
				  <xsl:otherwise>
					  <b><xsl:value-of select="//lcl/FAC/aanvrager"/>:</b>
					</xsl:otherwise>
					</xsl:choose>  
				</td>
				<td align="left" width="34%">
					<xsl:value-of select="melding/voor/naam_full"/>
				</td>
			</tr>
			<tr>
				<td align="right" width="16%">
					<b>
						<xsl:value-of select="//lcl/FAC/telefoon"/>:</b>
				</td>
				<td align="left" width="34%">
					<xsl:choose>
						<xsl:when test="melding/voor/afdeling//bedrijf/naam = 'Extern'">088-1861010</xsl:when>
						<xsl:otherwise>
							<xsl:choose>
								<xsl:when test="melding/voor/telefoonnr != ''">
									<xsl:value-of select="melding/voor/telefoonnr"/>
								</xsl:when>
								<xsl:when test="melding/voor/mobiel != ''">
									<xsl:if test="melding/voor/telefoonnr != ''">
										<br/>
									</xsl:if>
									<xsl:value-of select="melding/voor/mobiel"/>
								</xsl:when>
							</xsl:choose>
						</xsl:otherwise>
					</xsl:choose>
				</td>
			</tr>
			<xsl:choose>
			<xsl:when test="$opdrtype='offerte'">
			<tr>
				<td align="right" colspan="4">
					<i>Graag voor vragen m.b.t. deze offerteaanvraag contact opnemen via:</i>
				</td>
			</tr>
			</xsl:when>
			<xsl:when test="$opdrtype='klacht'">
			<tr>
				<td align="right" colspan="4">
					<i>Graag voor vragen m.b.t. deze klachtmelding contact opnemen via:</i>
				</td>
			</tr>
			</xsl:when>			
			<xsl:otherwise>
			<tr>
				<td align="right" colspan="4">
					<i>Graag voor vragen m.b.t. de uitvoering van deze opdracht contact opnemen via:</i>
				</td>
			</tr>
			</xsl:otherwise>
			</xsl:choose>
			<tr>
				<td align="right" width="16%">
					<b>Emailadres:</b>
				</td>
				<td align="left" width="34%">
					<xsl:choose>
						<xsl:when test="melding/voor/afdeling//bedrijf/naam = 'Extern'">
							<a href="mailto:fsb@pch-fm.nl">fsb@pch-fm.nl</a>
						</xsl:when>
						<xsl:otherwise>
							<xsl:element name="a">
								<xsl:attribute name="href">
									<xsl:text>mailto:</xsl:text>
									<xsl:value-of select="melding/voor/email"/>
								</xsl:attribute>
								<xsl:value-of select="melding/voor/email"/>
							</xsl:element>
						</xsl:otherwise>
					</xsl:choose>
				</td>
			</tr>
			<tr>
				<td colspan="4">
					<hr/>
				</td>
			</tr>			
			<tr>
				<td align="right" colspan="4">
					<i>Het betreft onze locatie:</i>
				</td>
			</tr>
			<tr>
				<td align="right">
					<b>
						<xsl:value-of select="//lcl/FAC/locatie"/>:</b>
				</td>
				<td align="left">
					<xsl:value-of select="melding/plaats/regio/district/locatie/code"/>&#xA0;
					<xsl:if test="melding/plaats/regio/district/locatie/omschrijving!=''">(<xsl:value-of select="melding/plaats/regio/district/locatie/omschrijving"/>)</xsl:if>
					<xsl:if test="not(melding/plaats/regio/district/locatie/gebouw/kenmerk[@key=10]!='')">
					<br/>
					<xsl:value-of select="melding/plaats/regio/district/locatie/adres"/>&#xA0;
					<br/>
					<xsl:value-of select="melding/plaats/regio/district/locatie/postcode"/>&#xA0;&#xA0;
					<xsl:value-of select="melding/plaats/regio/district/locatie/plaats"/>
					</xsl:if>
				</td>
				<td align="right">
				<xsl:choose>
				  <xsl:when test="$opdrtype='klacht'">
					  <b>Melddatum:</b>
			    </xsl:when>
			    <xsl:otherwise>
					  <b>Opdrachtdatum:</b>			    
			    </xsl:otherwise>
			  </xsl:choose>
				</td>
				<td align="left">
					<xsl:value-of select="datumbegin/datum"/>
				</td>
			</tr>
			<tr>
				<xsl:choose>
					<xsl:when test="meldding/plaats/@type='T'">
						<td align="right">
							<b>
								<xsl:value-of select="//lcl/FAC/terrein"/>:</b>
						</td>
						<td align="left">
							<xsl:value-of select="melding/plaats/regio/district/locatie/terrein/code"/>-<xsl:value-of select="melding/plaats/regio/district/locatie/terrein/naam"/></td>
					</xsl:when>
					<xsl:otherwise>
						<td align="right">
							<b>
								<xsl:value-of select="//lcl/FAC/gebouw"/>:</b>
						</td>
						<td align="left">
							<xsl:value-of select="melding/plaats/regio/district/locatie/gebouw/code"/>-<xsl:value-of select="melding/plaats/regio/district/locatie/gebouw/naam"/><br/>
							<xsl:if test="melding/plaats/regio/district/locatie/gebouw/kenmerk[@key=10]!=''">
								<xsl:value-of select="melding/plaats/regio/district/locatie/gebouw/kenmerk[@key='10']"/><br/>
								<xsl:value-of select="melding/plaats/regio/district/locatie/gebouw/kenmerk[@key='11']"/>&#xA0;&#xA0;<xsl:value-of select="melding/plaats/regio/district/locatie/gebouw/kenmerk[@key='12']"/><br/>
							</xsl:if>
						</td>
					</xsl:otherwise>
				</xsl:choose>
				  <xsl:choose>
				    <xsl:when test="$opdrtype='offerte'">
				    	<td align="right">
					    <b>Offerte graag aanleveren voor:</b>
					    </td>	
      				<td align="left">
      					<xsl:value-of select="einddatum/datum"/>
      				</td>					    
					</xsl:when>
				  <xsl:when test="$opdrtype='klacht'">
				    	<td colspan="2"/>			    
					</xsl:when>					
					<xsl:otherwise>
					    <td align="right">
					    <b>Gewenste uitvoering voor:</b>
					    </td>	
      				<td align="left">
      					<xsl:value-of select="einddatum/datum"/>
				     </td>
					</xsl:otherwise>
					</xsl:choose>
			</tr>
			<tr>
				<xsl:if test="melding/plaats/@type='T' or melding/plaats/@type='G'">
					<td colspan="2"/>
				</xsl:if>
				<xsl:if test="melding/plaats/@type!='T' and melding/plaats/@type!='G' and melding/plaats/regio/district/locatie/gebouw/verdieping/code != '-'">
					<td align="right">
						<b>
							<xsl:value-of select="//lcl/FAC/bouwlaag"/>:</b>
					</td>
					<td align="left">
						<xsl:value-of select="melding/plaats/regio/district/locatie/gebouw/verdieping/code"/>&#xA0;
						<xsl:if test="melding/plaats/regio/district/locatie/gebouw/verdieping/omschrijving!=''">(<xsl:value-of select="melding/plaats/regio/district/locatie/gebouw/verdieping/omschrijving"/>)</xsl:if>
					</td>
				</xsl:if>
			</tr>
			<tr>
				<xsl:if test="melding/plaats/@type='R' and melding/plaats/regio/district/locatie/gebouw/verdieping/ruimte/nr != '-'">
					<td align="right" valign="top">
						<b>
							<xsl:value-of select="//lcl/FAC/ruimte"/>:</b>
					</td>
					<td align="left">
						<xsl:value-of select="melding/plaats/regio/district/locatie/gebouw/verdieping/ruimte/nr"/>&#xA0;
						<xsl:if test="melding/plaats/regio/district/locatie/gebouw/verdieping/ruimte/omschrijving!=''">(<xsl:value-of select="melding/plaats/regio/district/locatie/gebouw/verdieping/ruimte/omschrijving"/>)</xsl:if>
					</td>
				</xsl:if>
				<xsl:if test="plaats/@type!='R'">
					<td colspan="2"/>
				</xsl:if>
				<td colspan="2"/>
			</tr>
			<xsl:if test="$opdrtype!='offerte'">
			<tr>
				<td align="right">
					<b>Contactpersoon op de locatie:</b>
				</td>
				<td align="left">
					<xsl:value-of select="melding/plaats/regio/district/locatie/kenmerk[@key=1000]/perslid/naam_full"/>
				</td>
			</tr>
			<tr>
				<td align="right" width="16%">
					<b><xsl:value-of select="//lcl/FAC/telefoon"/>:</b>
				</td>
				<td align="left" width="34%">
					<xsl:choose>
						<xsl:when test="melding/plaats/regio/district/locatie/kenmerk[@key=1000]/perslid/telefoonnr != ''">
							<xsl:value-of select="melding/plaats/regio/district/locatie/kenmerk[@key=1000]/perslid/telefoonnr"/>
						</xsl:when>
						<xsl:when test="melding/plaats/regio/district/locatie/kenmerk[@key=1000]/perslid/mobiel != ''">
							<xsl:if test="melding/plaats/regio/district/locatie/kenmerk[@key=1000]/perslid/telefoonnr != ''">
								<br/>
							</xsl:if>
							<xsl:value-of select="melding/plaats/regio/district/locatie/kenmerk[@key=1000]/perslid/mobiel"/>
						</xsl:when>
					</xsl:choose>
				</td>
			</tr>
			</xsl:if>
			<tr>
				<td colspan="4" height="30px" valign="center">
					<hr/>
				</td>
			</tr>
			<tr>
				<td align="right">
					<b>
						<xsl:value-of select="//lcl/MLD/stdmelding"/>:</b>
				</td>
				<td align="left">
					<xsl:if test="melding/stdmelding/omschrijving=''">-</xsl:if>
					<xsl:value-of select="melding/stdmelding/omschrijving"/>
				</td>
				<td align="right">
					<b>
						<xsl:value-of select="//lcl/MLD/vakgroep"/>:</b>
				</td>
				<td align="left">
					<xsl:if test="melding/discipline/omschrijving=''">-</xsl:if>
					<xsl:value-of select="melding/discipline/omschrijving"/>
				</td>
			</tr>
			<tr>
				<td align="right" valign="top">
					<b>
						<xsl:value-of select="//lcl/FAC/omschrijving"/>:</b>
				</td>
				<td align="left" colspan="3">
					<xsl:call-template name="linebreaks">
						<xsl:with-param name="string" select="omschrijving"/>
					</xsl:call-template>
				</td>
			</tr>
			<xsl:choose>
			<xsl:when test="$opdrtype='offerte'">
				<tr>
					<td colspan="4" align="left">
						<br/>Wij zien de offerte graag per omgaande tegemoet.</td>
				</tr>
			</xsl:when>
			<xsl:when test="$opdrtype='contract'">
				<tr>
					<td colspan="4" align="left">
						<br/><b><u>Graag zien wij een bevestiging van de opdracht tegemoet en vernemen wij de uitvoerdatum van de werkzaamheden.<br/> 
						Wij gaan er vanuit dat bovenstaande opdracht onder het contract valt, indien er wel kosten gemaakt worden dit graag in overleg met het Facilitaire Service Bureau.</u></b></td>
				</tr>
			</xsl:when>
			<xsl:when test="$opdrtype='opdracht'">
				<tr>
					<td colspan="4" align="left">
						<br/><b><u>Graag zien wij een bevestiging van de opdracht tegemoet en vernemen wij de uitvoerdatum van de werkzaamheden.<br/>
						Digitale facturen kunnen gestuurd worden naar <a href="mailto:fa@pch-dienstengroep.nl">fa@pch-dienstengroep.nl</a></u></b></td>
				</tr>
			</xsl:when>	
			<xsl:when test="$opdrtype='klacht'">
				<tr>
					<td colspan="4" align="left">
						<br/>Graag zien wij een bevestiging van deze klachtmelding tegemoet.</td>
				</tr>
			</xsl:when>								
			</xsl:choose>
			<xsl:if test="opdrachttype/kosten = '1'">
				<tr>
					<td colspan="4" height="30px" valign="center">
						<hr/>
					</td>
				</tr>
				<xsl:variable name="uurloon">
					<xsl:choose>
						<xsl:when test="uurloon">
							<xsl:value-of select="uurloon"/>
						</xsl:when>
						<xsl:otherwise>0</xsl:otherwise>
					</xsl:choose>
				</xsl:variable>
				<xsl:variable name="arbeid" select="uren*$uurloon"/>
				<tr>
					<td align="right">
						<b>
							<xsl:value-of select="//lcl/MLD/uren"/>:</b>
					</td>
					<td>
						<xsl:value-of select="format-number(uren, '0,00', 'european')"/>
						<b>&#xA0;à&#xA0;</b>&#x20AC;&#xA0;<xsl:value-of select="format-number($uurloon, '0,00', 'european')"/></td>
					<td align="right">
						<b>
							<xsl:value-of select="//lcl/MLD/arbeid"/>:</b>
					</td>
					<td style="width:1in;text-align:right">&#x20AC;&#xA0;<xsl:value-of select="format-number($arbeid, '0,00', 'european')"/></td>
				</tr>
				<tr>
					<td colspan="2"/>
					<td align="right">
						<b>
							<xsl:value-of select="//lcl/MLD/materiaal"/>:</b>
					</td>
					<td style="width:1in;text-align:right">&#x20AC;&#xA0;<xsl:value-of select="format-number(materiaal, '0,00', 'european')"/></td>
				</tr>
				<xsl:variable name="correctie0" select="$arbeid + materiaal"/>
				<xsl:variable name="correctie" select="kosten - $correctie0"/>
				<xsl:if test="$correctie!=0">
					<tr>
						<td colspan="2"/>
						<td align="right">
							<b>
								<xsl:value-of select="//lcl/MLD/correctie"/>:</b>
						</td>
						<td style="width:1in;text-align:right">&#x20AC;&#xA0;<xsl:value-of select="format-number($correctie, '0,00', 'european')"/></td>
					</tr>
				</xsl:if>
				<tr>
					<td colspan="2"/>
					<td align="right">
						<b>
							<xsl:value-of select="//lcl/FAC/totaal"/>
							<xsl:if test="kenmerk[@key=41] = 'Ja'">&#xA0;(indicatief)</xsl:if>:</b>
					</td>
					<td style="width:1in;text-align:right">
						<b>&#x20AC;&#xA0;<xsl:value-of select="format-number(kosten, '0,00', 'european')"/></b>
					</td>
				</tr>
				<tr>
					<td colspan="4" align="left">
						<xsl:if test="kenmerk[@key=41] = 'Ja'">
							<br/>Het bovenstaande bedrag is indicatief. Indien het bedrag hoger wordt, dient eerst contact opgenomen te worden met het Facilitair Service Bureau.<br/></xsl:if>
						<br/>De factuur dient (inclusief werkbon en kopie opdrachtbevestiging) onder vermelding van
				opdrachtnummer <xsl:value-of select="//facilitor/header/custId"/>&#xA0;<xsl:value-of select="melding/stdmelding/discipline/srtdiscipline/prefix"/>
						<xsl:value-of select="melding/key"/>/<xsl:value-of select="bedrijfopdr_volgnr"/> gezonden te
						worden naar:<br/><br/>
						<xsl:value-of select="melding/plaats/regio/district/locatie/kenmerk[@key=1060]"/>
						<br/>Postbus 4358<br/>
             7320&#xA0;AJ&#xA0;&#xA0;Apeldoorn<br/>
						<br/>Facturen zonder referentie, kopie zullen worden geretourneerd. De factuur <b>uiterlijk 3 weken na oplevering</b> toezenden.</td>
				</tr>
			</xsl:if>
			<tr>
				<td colspan="4" height="30px" valign="center">
				</td>
			</tr>
			<xsl:if test="opdrachttype/key = 5 or opdrachttype/key = 702">
			</xsl:if>
		</table>
	</xsl:template>

	<xsl:template match="melding" mode="full">
		<xsl:choose>
			<xsl:when test="$mode='summary'"></xsl:when>
			<xsl:otherwise>
				<html>
					<xsl:comment>================================ MELDINGEN ==============================</xsl:comment>
					<xsl:comment>FACILITOR default XSL template for melding</xsl:comment>
					<xsl:call-template name="htmlhead"/>
					<xsl:element name="body">
						<xsl:call-template name="pageheader"/>
						<xsl:choose>
							<xsl:when test="$srtnotificatiecode = 'MLDKTO'">
								<xsl:apply-templates select="." mode="kto"/>
							</xsl:when>
							<xsl:otherwise>
								<xsl:apply-templates select="." mode="include"/>
							</xsl:otherwise>
						</xsl:choose>
						<xsl:call-template name="pagefooter"/>
					</xsl:element>
				</html>
			</xsl:otherwise>
		</xsl:choose>
	</xsl:template>

	<xsl:template match="opdracht" mode="full">
		<xsl:choose>
			<xsl:when test="$mode='summary'"></xsl:when>
			<xsl:otherwise>
				<html>
					<xsl:comment>================================ OPDRACHTEN ==============================</xsl:comment>
					<xsl:comment>FACILITOR default XSL template for opdracht</xsl:comment>
					<xsl:call-template name="htmlhead"/>
					<xsl:element name="body">
						<xsl:call-template name="pageheader"/>
						<xsl:apply-templates select="." mode="include"/>
						<xsl:call-template name="pagefooter"/>
					</xsl:element>
				</html>
			</xsl:otherwise>
		</xsl:choose>
	</xsl:template>

	<xsl:template name="qrc_ins_new_page">
		<xsl:param name="p_page"/>
		<xsl:param name="p_rows"/>
		<xsl:param name="p_cols"/>
		<table>
			<xsl:for-each select="//facilitor/rapport/rapport_data/data_row">
				<xsl:sort select="FCLT_F_GEBOUW"/>
				<xsl:sort select="FCLT_F_VERDIEPING"/>
				<xsl:sort select="PLAATS"/>
				<xsl:if test="position() &gt;= (($p_page - 1) * ($p_rows * $p_cols) + 1) and position() &lt;= ($p_page * ($p_rows * $p_cols))">
					<xsl:if test="(position() mod $p_cols) = 0">
						<xsl:comment>=== Na elke 1 records (1x1 passen op 1 regel) ===</xsl:comment>
						<xsl:call-template name="qrc_ins_new_tr">
							<xsl:with-param name="p_pos" select="position() - $p_cols + 1"/>
							<xsl:with-param name="p_cols" select="$p_cols"/>
						</xsl:call-template>
					</xsl:if>
					<xsl:if test="(position() = last()) and (position() mod $p_cols) != 0">
						<xsl:comment>=== Na elke 1 records (1x1 passen op 1 regel) ===</xsl:comment>
						<xsl:call-template name="qrc_ins_new_tr">
							<xsl:with-param name="p_pos" select="floor(position() div $p_cols) * $p_cols + 1"/>
							<xsl:with-param name="p_cols" select="$p_cols"/>
						</xsl:call-template>
					</xsl:if>
				</xsl:if>
			</xsl:for-each>
		</table>
	</xsl:template>

	<xsl:template name="qrc_ins_new_tr">
		<xsl:param name="p_pos"/>
		<xsl:param name="p_cols"/>
		<tr height="80px">
			<xsl:for-each select="//facilitor/rapport/rapport_data/data_row">
				<xsl:sort select="FCLT_F_SOORTMELDING"/>
				<xsl:sort select="FCLT_F_LOCATIE"/>
				<xsl:sort select="FCLT_F_GEBOUW"/>
				<xsl:sort select="FCLT_F_VERDIEPING"/>
				<xsl:sort select="PLAATS"/>
				<xsl:sort select="FCLT_F_OBJECTGROEP"/>
				<xsl:sort select="FCLT_F_OBJECTSOORT"/>
				<xsl:sort select="INS_DEEL_OMSCHRIJVING"/>
				<xsl:if test="position() &gt;= $p_pos and position() &lt;= $p_pos + $p_cols - 1">
					<xsl:choose>
						<xsl:when test="VARIABELE = 'INS_KEY'">
					<td width="25%" style="text-align:center">
						<xsl:element name="img">
							<xsl:attribute name="style">height: 5cm</xsl:attribute>
							<xsl:attribute name="src">
								../../appl/shared/qrcode.asp?size=16&amp;text=%3Fu%3D<xsl:value-of select="HIDE_F_BOOKMARK_ID"/>%26ins_key%3D<xsl:value-of select="INS_DEEL_KEY"/>
							</xsl:attribute>
						</xsl:element>
						<br/>
					</td>
						</xsl:when>
						<xsl:when test="VARIABELE = 'RES_RUIMTE_KEY'">
					<td width="25%" style="text-align:center">
						<xsl:element name="img">
							<xsl:attribute name="style">height: 5cm</xsl:attribute>
							<xsl:attribute name="src">
								../../appl/shared/qrcode.asp?size=16&amp;text=%3Fu%3D<xsl:value-of select="HIDE_F_BOOKMARK_ID"/>%26res_ruimte_key%3D<xsl:value-of select="RUIMTE_KEY"/>
							</xsl:attribute>
						</xsl:element>
						<br/>
					</td>
						</xsl:when>
						<xsl:otherwise>
						</xsl:otherwise>
					</xsl:choose>
				</xsl:if>
			</xsl:for-each>
		</tr>
		<tr height="80px">
			<xsl:for-each select="//facilitor/rapport/rapport_data/data_row">
				<xsl:sort select="FCLT_F_SOORTMELDING"/>
				<xsl:sort select="FCLT_F_LOCATIE"/>
				<xsl:sort select="FCLT_F_GEBOUW"/>
				<xsl:sort select="FCLT_F_VERDIEPING"/>
				<xsl:sort select="PLAATS"/>
				<xsl:sort select="FCLT_F_OBJECTGROEP"/>
				<xsl:sort select="FCLT_F_OBJECTSOORT"/>
				<xsl:sort select="INS_DEEL_OMSCHRIJVING"/>
				<xsl:if test="position() &gt;= $p_pos and position() &lt;= $p_pos + $p_cols - 1">
					<td width="25%" style="text-align:center">
						<xsl:value-of select="FCLT_F_SOORTMELDING"/>
						<br/>
						<xsl:value-of select="FCLT_F_LOCATIE"/>
						<br/>
						<xsl:value-of select="PLAATS"/>
						<br/>
						<xsl:value-of select="FCLT_F_OBJECTGROEP"/>
						<br/>
						<xsl:value-of select="FCLT_F_OBJECTSOORT"/>
						<br/>
						<xsl:value-of select="INS_DEEL_OMSCHRIJVING"/>
						<br/>
					</td>
				</xsl:if>
			</xsl:for-each>
		</tr>
	</xsl:template>

	<xsl:template match="rapport">
		<xsl:choose>

		<!--De generatie van QR-codes voor object-meldingen en reserveringen)-->
		<xsl:when test="@view = 'pchx_v_rap_mld_qrc' or @view = 'PCHX_V_RAP_MLD_QRC'">
			<xsl:variable name="p_rows" select="3"/>
			<xsl:variable name="p_cols" select="2"/>

			<table>
				<tr height="200">
					<td width="50%" align="center">
						<span style="font-size:24pt;color:#000000">QR-codes</span>
					</td>
				</tr>
				<tr height="200">
					<td width="50%" align="center">
						<span style="font-size:24pt;color:#000000">object-meldingen</span>
					</td>
				</tr>
				<tr height="200">
					<td width="50%" align="center">
						<span style="font-size:24pt;color:#000000">(startpagina tbv. uitlijning)</span>
					</td>
				</tr>
			</table>

			<xsl:for-each select="//facilitor/rapport/rapport_data/data_row">
				<xsl:sort select="FCLT_F_SOORTMELDING"/>
				<xsl:sort select="FCLT_F_LOCATIE"/>
				<xsl:sort select="FCLT_F_GEBOUW"/>
				<xsl:sort select="FCLT_F_VERDIEPING"/>
				<xsl:sort select="PLAATS"/>
				<xsl:sort select="FCLT_F_OBJECTGROEP"/>
				<xsl:sort select="FCLT_F_OBJECTSOORT"/>
				<xsl:sort select="INS_DEEL_OMSCHRIJVING"/>
				<xsl:if test="position() mod ($p_rows * $p_cols) = 0">
					<div style="page-break-before:always">&#160;</div>
					<xsl:comment>=== Na elke 2 records (2x1 passen op 1 A4) =====</xsl:comment>
					<xsl:call-template name="qrc_ins_new_page">
						<xsl:with-param name="p_page" select="floor(position() div ($p_rows * $p_cols))"/>
						<xsl:with-param name="p_rows" select="$p_rows"/>
						<xsl:with-param name="p_cols" select="$p_cols"/>
					</xsl:call-template>
				</xsl:if>
				<xsl:if test="position() = last() and position() mod ($p_rows * $p_cols) != 0 ">
					<div style="page-break-before:always">&#160;</div>
					<xsl:comment>=== De laatste paar, zijn minder dan 2 =====</xsl:comment>
					<xsl:call-template name="qrc_ins_new_page">
						<xsl:with-param name="p_page" select="floor((position() div ($p_rows * $p_cols)) + 1)"/>
						<xsl:with-param name="p_rows" select="$p_rows"/>
						<xsl:with-param name="p_cols" select="$p_cols"/>
					</xsl:call-template>
				</xsl:if>
			</xsl:for-each>
		</xsl:when>

		<xsl:otherwise>
			<xsl:apply-templates select="." mode="cust"/>
		</xsl:otherwise>
		</xsl:choose>
	</xsl:template>
</xsl:stylesheet>