<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
	<xsl:output method="xml" encoding="utf-8"/>

	<xsl:variable name="Rev">
		<xsl:value-of select="substring(translate('$Revision$', '$ ', ''), 10)"/>
	</xsl:variable>

	<xsl:decimal-format name="european" decimal-separator="." grouping-separator=","/>

	<xsl:param name="mode"/>

	<xsl:template match="bestelopdracht">
		<!--Facilitor custom XSL template for cXML bestelopdracht-->
		<xsl:element name="cXML">
			<xsl:attribute name="version">1.2.016</xsl:attribute>
			<xsl:attribute name="payloadID"><xsl:value-of select="key"/></xsl:attribute>
			<xsl:attribute name="timestamp"><xsl:value-of select="datum/jaar"/>-<xsl:value-of select="datum/maand"/>-<xsl:value-of select="datum/dag"/>T<xsl:value-of select="datum/tijd"/>:00+01:00</xsl:attribute>
			<xsl:attribute name="xml:lang">NL</xsl:attribute>
			<Header>
				<From>
					<xsl:element name="Credential">
						<xsl:attribute name="domain"><xsl:value-of select="/facilitor/header/custId"/></xsl:attribute>
						<Identity><xsl:choose><xsl:when test="bedrijf/key='30341'">order@facilityplace.nl</xsl:when></xsl:choose></Identity>
					</xsl:element>
				</From>
				<To>
					<xsl:element name="Credential">
						<xsl:attribute name="domain"><xsl:value-of select="bedrijf/naam"/></xsl:attribute>
						<Identity><xsl:choose><xsl:when test="bedrijf/key='30341'">8712423002180</xsl:when></xsl:choose></Identity>								
					</xsl:element>
				</To>
				<Sender>
					<Credential domain="Facilitor">
						<Identity>
							<xsl:choose>
								<xsl:when test="bedrijf/key='49742'">OciWehkamp</xsl:when>
								<xsl:otherwise>order@facilityplace.nl</xsl:otherwise>
							</xsl:choose></Identity>
					</Credential>
					<UserAgent/>
				</Sender>
			</Header>
			<Request>
				<OrderRequest>
					<xsl:element name="OrderRequestHeader">
						<xsl:attribute name="orderID"><xsl:value-of select="id"/></xsl:attribute>
						<xsl:attribute name="orderDate"><xsl:value-of select="datum/jaar"/>-<xsl:value-of select="datum/maand"/>-<xsl:value-of select="datum/dag"/></xsl:attribute>
						<Total>
							<Money currency="EUR"><xsl:value-of select="format-number(sum(bestelopdrachtitem/totaal), '0.00', 'european')"/></Money>
						</Total>
						<ShipTo>
							<xsl:element name="Address">
								<xsl:attribute name="addressID">
									<xsl:choose>
										<xsl:when test="bedrijf/key='30341'"><xsl:value-of select="substring-before(bestelling/kenmerk[@naam='debiteurennummer'],' ')"/></xsl:when><!--WEHK#34722 flexkenmerk debiteurennummer (key 222 en 223) bij bedrijf Staples (30341)-->
										<xsl:when test="bedrijf/key='49742'"><xsl:value-of select="substring-before(bestelling/kenmerk[@naam='debiteurennummer'],' ')"/></xsl:when><!--WEHK#34868 flexkenmerk debiteurennummer (key XXXX) bij bedrijf SMG(49742)-->
									</xsl:choose></xsl:attribute>
								<Name xml:lang="NL"><xsl:value-of select="afleveradres/naam"/></Name>
								<PostalAddress>
									<DeliverTo><xsl:value-of select="bestelling/aanvrager/naam_full"/></DeliverTo>
									<Street><xsl:value-of select="bestelling/afleveradres/bezoek_adres"/></Street>
									<City><xsl:value-of select="bestelling/afleveradres/bezoek_plaats"/></City>
									<State/>
									<PostalCode><xsl:value-of select="bestelling/afleveradres/bezoek_postcode"/></PostalCode>
									<Country isoCountryCode="NL"><xsl:value-of select="bestelling/afleveradres/bezoek_land"/></Country>
								</PostalAddress>
							</xsl:element>
						</ShipTo>
						<BillTo>
							<xsl:element name="Address">
								<!--xsl:attribute name="addressID"><xsl:value-of select="bedrijf/overeenkomst_nr"/></xsl:attribute-->
								<!--xsl:attribute name="addressID"><xsl:value-of select="factuuradres/gebouw_ruimte"/>bill-to number???</xsl:attribute-->
								<xsl:attribute name="addressID"><xsl:choose><xsl:when test="bedrijf/key='30341'">400013434</xsl:when></xsl:choose></xsl:attribute>
								<Name xml:lang="NL"><xsl:value-of select="factuuradres/naam"/></Name>
								<PostalAddress>
									<Street><xsl:value-of select="factuuradres/post_adres"/></Street>
									<City><xsl:value-of select="factuuradres/post_plaats"/></City>
									<State/>
									<PostalCode><xsl:value-of select="factuuradres/post_postcode"/></PostalCode>
									<Country isoCountryCode="NL"><xsl:value-of select="factuuradres/post_land"/></Country>
								</PostalAddress>
							</xsl:element>
						</BillTo>
						<Contact>
							<Name xml:lang="NL"><xsl:value-of select="bestelling/aanvrager/naam_full"/></Name>
							<Email><xsl:value-of select="bestelling/aanvrager/email"/></Email>
						</Contact>
						<Extrinsic name="Costcenter"><xsl:value-of select="bestelling/kostenplaats/nr"/></Extrinsic>
					</xsl:element>
					<xsl:for-each select="bestelopdrachtitem">
						<xsl:sort select="srtdeel/omschrijving"/>
						<xsl:sort select="posnr"/>
						<xsl:element name="ItemOut">
							<xsl:attribute name="quantity"><xsl:value-of select="aantal"/></xsl:attribute>
							<xsl:attribute name="lineNumber"><xsl:value-of select="posnr"/></xsl:attribute>
							<!--xsl:attribute name="requestedDeliveryDate">Leeg=ASAP bij Staples???</xsl:attribute-->
							<xsl:attribute name="requestedDeliveryDate"><xsl:choose><xsl:when test="bedrijf/key!='30341'"><xsl:value-of select="../bestelling/leverdatum/jaar"/>-<xsl:value-of select="../bestelling/leverdatum/maand"/>-<xsl:value-of select="../bestelling/leverdatum/dag"/></xsl:when></xsl:choose></xsl:attribute>
							<ItemID>
								<SupplierPartID><xsl:value-of select="bestelitem/srtdeel/artikel_nummer"/></SupplierPartID>
							</ItemID>
							<ItemDetail>
								<UnitPrice>
									<Money currency="EUR"><xsl:value-of select="format-number(prijs, '0.00', 'european')"/></Money>
								</UnitPrice>
								<Description xml:lang="NL"><xsl:value-of select="bestelitem/srtdeel/omschrijving"/></Description>
								<UnitOfMeasure><xsl:value-of select="bestelitem/srtdeel/eenheid"/></UnitOfMeasure>
								<Classification domain=""/>
							</ItemDetail>
						</xsl:element>
					</xsl:for-each>
				</OrderRequest>
			</Request>
		</xsl:element>
	</xsl:template>

	<xsl:template match="facilitor">
		<xsl:apply-templates select="bestelopdracht"/>
	</xsl:template>

	<xsl:template match="/">
		<xsl:choose>
			<xsl:when test="$mode='getExtension'">
				<xsl:element name="format">
					<xsl:element name="extension">xml</xsl:element>
				</xsl:element>
			</xsl:when>
			<xsl:otherwise>
				<xsl:apply-templates select="facilitor"/>
			</xsl:otherwise>
		</xsl:choose>
	</xsl:template>
</xsl:stylesheet>
<!-- Stylus Studio meta-information - (c) 2004-2007. Progress Software Corporation. All rights reserved.
<metaInformation>
<scenarios ><scenario default="yes" name="Scenario1" userelativepaths="yes" externalpreview="no" url="..\..\..\TEMP\WEHK_files\bestelopdr1467_20160301170830.xml" htmlbaseurl="" outputurl="" processortype="internal" useresolver="yes" profilemode="0" profiledepth="" profilelength="" urlprofilexml="" commandline="" additionalpath="" additionalclasspath="" postprocessortype="none" postprocesscommandline="" postprocessadditionalpath="" postprocessgeneratedext="" validateoutput="no" validator="internal" customvalidator=""/></scenarios><MapperMetaTag><MapperInfo srcSchemaPathIsRelative="yes" srcSchemaInterpretAsXML="no" destSchemaPath="" destSchemaRoot="" destSchemaPathIsRelative="yes" destSchemaInterpretAsXML="no"/><MapperBlockPosition></MapperBlockPosition><TemplateContext></TemplateContext><MapperFilter side="source"></MapperFilter></MapperMetaTag>
</metaInformation>
-->