<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
	<xsl:import href="./tmp_default.xsl"/>

	<!-- Defaults hier definiëren, zodat de boel backwards compatible blijft.
       Anders moet je ze in iedere cust.xsl definiëren, wil je geen '... undifined' foutmeldingen krijgen! -->
	<xsl:variable name="logo_file">../../cust/aaxx/aafm_banner.gif</xsl:variable>
	<xsl:template name="customer">Onbekend</xsl:template>
	<xsl:template name="customer_code">Onbekend</xsl:template>
	<xsl:template name="customer_email">Onbekend</xsl:template>
	<xsl:template name="invoice_email"></xsl:template>
	<xsl:template name="servicedesk_telefoon">Onbekend</xsl:template>
	<xsl:template name="opdracht_qr_bookmark"></xsl:template>

	<xsl:template match="opdracht" mode="default_opdracht">
		<xsl:variable name="overeenkomst_nr">
			<xsl:value-of select="uitvoerende/bedrijf/overeenkomst_nr"/>
			<xsl:if test="uitvoerende/bedrijf/opmerking2 != ''"> (<xsl:value-of select="uitvoerende/bedrijf/opmerking2"/>)
			</xsl:if>
		</xsl:variable>
		<xsl:variable name="opdracht_qr_bookmark">
			<xsl:call-template name="opdracht_qr_bookmark"/>
		</xsl:variable>
		<xsl:variable name="customer">
			<xsl:call-template name="customer"/>
		</xsl:variable>
		<xsl:variable name="customer_code">
			<xsl:call-template name="customer_code"/>
		</xsl:variable>
		<xsl:variable name="telnr">
			<xsl:choose>
				<xsl:when test="melding/plaats/regio/district/locatie/gebouw/verantwoordelijke">
					<xsl:choose>
						<xsl:when test="melding/plaats/regio/district/locatie/gebouw/verantwoordelijke/telefoonnr != ''">
							<xsl:value-of select="melding/plaats/regio/district/locatie/gebouw/verantwoordelijke/telefoonnr"/>
						</xsl:when>
						<xsl:otherwise>
							<xsl:value-of select="melding/plaats/regio/district/locatie/gebouw/verantwoordelijke/mobiel"/>
						</xsl:otherwise>
					</xsl:choose>
				</xsl:when>
				<xsl:otherwise>
					<xsl:choose>
						<xsl:when test="backoffice_contact/telefoonnr != ''">
							<xsl:value-of select="backoffice_contact/telefoonnr"/>
						</xsl:when>
						<xsl:otherwise>
							<xsl:value-of select="backoffice_contact/mobiel"/>
						</xsl:otherwise>
					</xsl:choose>
				</xsl:otherwise>
			</xsl:choose>
		</xsl:variable>
		<xsl:variable name="email">
			<xsl:choose>
				<xsl:when test="melding/plaats/regio/district/locatie/gebouw/verantwoordelijke">
					<xsl:value-of select="melding/plaats/regio/district/locatie/gebouw/verantwoordelijke/email"/>
				</xsl:when>
				<xsl:otherwise>
					<xsl:value-of select="backoffice_contact/email"/>
				</xsl:otherwise>
			</xsl:choose>
		</xsl:variable>
		<xsl:variable name="relatietype">
			<xsl:choose>
				<xsl:when test="uitvoerende/bedrijf/relatietype/omschrijving = 'Managing Agent'">MA</xsl:when>
				<xsl:otherwise>CP</xsl:otherwise>
			</xsl:choose>
		</xsl:variable>
		<xsl:choose>
			<xsl:when test="$mode='summary'"/>
			<xsl:otherwise>
				<html>
					<xsl:comment>================================ OPDRACHT ==============================</xsl:comment>
					<xsl:comment>AAFM new style default XSL template for contract</xsl:comment>
					<xsl:call-template name="htmlhead"/>
					<xsl:element name="body">
						<xsl:if test="$mode!='email'">
							<xsl:attribute name="onload">window.print();</xsl:attribute>
						</xsl:if>
						<xsl:call-template name="pageheader_aaxx">
							<xsl:with-param name="opdr_type" select="opdrachttype/omschrijving"/>
							<xsl:with-param name="customer_id" select="//facilitor/header/custId"/>
						</xsl:call-template>
						<br/>
						<br/>
						<br/>
						<xsl:apply-templates select="uitvoerende/bedrijf"/>
						<br/>
						<br/>
						<br/>
						<table width="100%" border="0">
							<tbody>
								<tr>
									<td class="label" width="12%">Datum</td>
									<td class="seperator" width="1%">|</td>
									<td class="value" width="18%">
										<xsl:value-of select="concat(/facilitor/header/dateDay,'-',/facilitor/header/dateMonth, '-', /facilitor/header/dateYear)"/>
									</td>
									<td class="label" width="10%">Contact</td>
									<td class="seperator" width="1%">|</td>
									<td class="value" width="30%">
										<xsl:choose>
											<xsl:when test="melding/plaats/regio/district/locatie/gebouw/verantwoordelijke">
												<xsl:value-of select="melding/plaats/regio/district/locatie/gebouw/verantwoordelijke/naam_friendly"/>
											</xsl:when>
											<xsl:otherwise>
												<xsl:value-of select="backoffice_contact/naam_friendly"/>
											</xsl:otherwise>
										</xsl:choose>
									</td>
									<td class="label" width="10%">Telefoon</td>
									<td class="seperator" width="1%">|</td>
									<td class="value" width="10%">
										<xsl:value-of select="$telnr"/>
									</td>
								</tr>
								<tr>
									<td class="label">Ons kenmerk</td>
									<td class="seperator">|</td>
									<td class="value">
										<xsl:value-of select="concat($customer_code, ' ', melding/discipline/srtdiscipline/prefix, melding/key, '/', bedrijfopdr_volgnr)"/>
									</td>
									<td class="label">E-mail</td>
									<td class="seperator">|</td>
									<td class="value" colSpan="4">
										<xsl:value-of select="$email"/>
									</td>
									<td/>
								</tr>
								<tr>
									<td colSpan="9" height="10"/>
								</tr>
								<tr>
									<td class="label" width="10%">Onderwerp</td>
									<td class="seperator" width="1%">|</td>
									<td class="value" colSpan="7">
										<xsl:choose>
											<xsl:when test="opdrachttype/omschrijving = 'RFQ'">Offerteaanvraag (RFQ) voor:</xsl:when>
											<xsl:otherwise>Opdracht voor:</xsl:otherwise>
										</xsl:choose>&#xA0;
										<xsl:value-of select="melding/stdmelding/omschrijving"/>
									</td>
								</tr>
							</tbody>
						</table>
						<br/>
						<br/>
						<br/>
						<table width="100%" border="0">
							<tbody>
								<tr>
									<td width="100%">Geachte
										<xsl:choose>
											<xsl:when test="contactpersoon">
												<xsl:value-of select="concat(contactpersoon/voornaam, ' ', contactpersoon/naam)"/>,</xsl:when>
											<xsl:otherwise>heer/mevrouw,</xsl:otherwise>
										</xsl:choose>

										<br/>
										<br/>
										<xsl:choose>
											<xsl:when test="opdrachttype/omschrijving = 'RFQ'">Hierbij verzoeken wij u ons een offerte te doen toekomen voor navolgende werkzaamheden:<br/>
												<xsl:call-template name="linebreaks">
													<xsl:with-param name="string" select="omschrijving"/>
												</xsl:call-template>
												<br/>
												<br/>Uw offerte dient een bindend en onherroepelijk aanbod te bevatten en dient door u tenminste 60 dagen gestand te worden gedaan. <br/>
                                            Het aanbod dient een vaste prijs te bevatten voor de bovenvermelde werkzaamheden. Indien niet kan worden overgegaan tot het uitbrengen van een opgave van een vaste prijs dient dit gemotiveerd te worden en dient een zo nauwkeurig mogelijke raming  te worden afgegeven. <br/>
                                            Voor nadere informatie kunt u zich wenden tot bovenvermelde contactpersoon.<br/><br/>
                                            Uw offerte dient uiterlijk 5 werkdagen na ontvangst ingediend te zijn.<br/><br/>
												<u>Voorwaarden en condities:</u>
												<br/>
												<xsl:choose>
													<xsl:when test="uitvoerende/bedrijf/overeenkomst_nr">Op deze offerteaanvraag en een op basis hiervan te verstrekken opdracht zijn uitsluitend en onverkort de voorwaarden en condities van <xsl:if test="$relatietype = 'MA'">uw</xsl:if> opdrachtovereenkomst nr. <xsl:value-of select="$overeenkomst_nr"/> d.d.
														<xsl:value-of select="uitvoerende/bedrijf/overeenkomst_datum/datum"/>
														<xsl:if test="$relatietype = 'MA'"> met <xsl:value-of select="$customer"/></xsl:if> van toepassing. <xsl:if test="$relatietype = 'MA'"> Opdrachtverlening door AAFM geschiedt namens en voor rekening van
															<xsl:value-of select="$customer"/>.</xsl:if></xsl:when>
													<xsl:otherwise>Op deze offerteaanvraag en een op basis hiervan te verstrekken opdracht zijn uitsluitend en onverkort de bijgevoegde Algemene Inkoopvoorwaarden van AAFM Facility Management BV van toepassing. Andere voorwaarden zijn niet van toepassing en worden hierbij nadrukkelijk van de hand gewezen.</xsl:otherwise>
												</xsl:choose>
											</xsl:when>
											<xsl:otherwise>
												Hiermede verzoeken wij u de navolgende werkzaamheden uit te voeren:<br/>
												<xsl:call-template name="linebreaks">
													<xsl:with-param name="string" select="omschrijving"/>
												</xsl:call-template>
												<xsl:if test="$relatietype='CP'"> t.b.v. <xsl:value-of select="$customer"/><br/></xsl:if>
												<br/>
												<xsl:if test="opdrachttype/omschrijving = 'Workorder'">
													<xsl:choose>
														<xsl:when test="kosten = 0">Op deze order is geen bedrag vermeld. Bij acceptatie van deze order kunt u (evt. na overleg met FM) aanvangen met de uitvoering van de werkzaamheden en dient u de werkelijke kosten met een maximum van €500,- binnen 8 werkdagen terug te koppelen aan de Servicedesk. Indien u verwacht dat de kosten >€500,- zullen zijn, dient u de opdracht te annuleren en bij de Servicedesk een RFQ aan te vragen. LET OP: het factuurbedrag mag NIET afwijken van de opgegeven kosten.</xsl:when>
														<xsl:otherwise>De werkzaamheden en/of leveranties dienen te worden uitgevoerd voor een vast totaalbedrag  van: € <xsl:value-of select="format-number(kosten, '0,00', 'european')"/> (excl. BTW).</xsl:otherwise>
													</xsl:choose>
													<br/>
													<br/>
												</xsl:if>
												<br/>
												<xsl:if test="opdrachttype/omschrijving = 'Workorder' or opdrachttype/omschrijving = 'Docket'">
													<br/>
														Werkzaamheden gereed: <xsl:value-of select="einddatum/datum"/><xsl:if test="einddatum/tijd != '00:00'">&#xA0;<xsl:value-of select="einddatum/tijd"/></xsl:if><br/>
														Gereedmelding van werkzaamheden via Facilitor, wanneer u geen toegang heeft kan dit per mail via <xsl:call-template name="customer_email"></xsl:call-template>.<br/>
												</xsl:if>
												<br/>
												<u>Voorwaarden en condities:</u>
												<br/>
												<br/>
												<xsl:if test="$relatietype='MA'">Op deze opdracht zijn uitsluitend en onverkort de voorwaarden en condities van uw opdrachtovereenkomst nr. <xsl:value-of select="$overeenkomst_nr"/> d.d.
													<xsl:value-of select="uitvoerende/bedrijf/overeenkomst_datum/datum"/>
													<xsl:if test="$relatietype = 'MA'"> met <xsl:value-of select="$customer"/></xsl:if> van toepassing behoudens voor zover in deze opdracht uitdrukkelijk anders bepaald. Opdrachtverlening door AAFM geschiedt namens en voor rekening van
													<xsl:value-of select="$customer"/>.</xsl:if>
												<xsl:if test="$relatietype='CP'">
													<xsl:choose>
														<xsl:when test="uitvoerende/bedrijf/overeenkomst_nr">Op deze opdracht zijn uitsluitend en onverkort de voorwaarden en condities van opdrachtovereenkomst nr. <xsl:value-of select="$overeenkomst_nr"/> d.d.
															<xsl:value-of select="uitvoerende/bedrijf/overeenkomst_datum/datum"/> van toepassing behoudens voor zover in deze opdracht uitdrukkelijk anders bepaald.</xsl:when>
														<xsl:otherwise>Op deze opdracht zijn de bijgevoegde Algemene Inkoopvoorwaarden van AAFM Facility Management BV van toepassing. Andere voorwaarden zijn niet van toepassing en worden hierbij nadrukkelijk van de hand gewezen.</xsl:otherwise>
													</xsl:choose>
												</xsl:if>
												<br/>
												<br/>
											</xsl:otherwise>
										</xsl:choose>
									</td>
								</tr>
							</tbody>
						</table>
						<table borderColor="#000000" cellPadding="10" border="1">
							<tbody>
								<tr>
									<td width="300px">
										<u>Bezoek/afleveradres:</u>
										<br/>
										<xsl:value-of select="$customer"/>
										<br/>Locatie: <xsl:value-of select="melding/plaats/regio/district/locatie/code"/>&#xA0;<xsl:value-of select="melding/plaats/regio/district/locatie/omschrijving"/>
										<br/>Gebouw: <xsl:value-of select="melding/plaats/regio/district/locatie/gebouw/omschrijving"/>
										<br/>Verdieping: <xsl:value-of select="melding/plaats/regio/district/locatie/gebouw/verdieping/omschrijving"/>
										<br/>Ruimte: <xsl:value-of select="melding/plaats/regio/district/locatie/gebouw/verdieping/ruimte/nr"/> (<xsl:value-of select="melding/plaats/regio/district/locatie/gebouw/verdieping/ruimte/omschrijving"/>)</td>
									<xsl:if test="opdrachttype/omschrijving != 'Docket'">
										<td width="300px">
											<u>
												<xsl:choose>
													<xsl:when test="opdrachttype/omschrijving = 'RFQ'">Offerte </xsl:when>
													<xsl:otherwise>Rekeningen </xsl:otherwise>
												</xsl:choose>s.v.p. sturen naar:</u>
											<br/>
											<xsl:choose>
												<xsl:when test="$relatietype='MA'">
													<xsl:choose>
														<xsl:when test="opdrachttype/omschrijving != 'RFQ'">
															<xsl:value-of select="$customer"/>
															<br/>P/A Crediteurenadministratie account </xsl:when>
														<xsl:otherwise>AAFM Facility Management B.V.<br/>T.a.v.</xsl:otherwise>
													</xsl:choose>
												</xsl:when>
												<xsl:otherwise>AAFM Facility Management B.V.<br/>T.a.v. <xsl:if test="opdrachttype/omschrijving != 'RFQ'">Crediteurenadministratie account </xsl:if></xsl:otherwise>
											</xsl:choose>
											<xsl:value-of select="$customer"/>
											<br/>Postbus 80009
											<br/>5600 JZ Eindhoven
											<xsl:if test="opdrachttype/omschrijving != 'RFQ'">
												<br/><xsl:call-template name="invoice_email"/>
											</xsl:if>
											<xsl:choose>
													<xsl:when test="opdrachttype/omschrijving = 'RFQ'"><br/><xsl:call-template name="customer_email"></xsl:call-template></xsl:when>
													<xsl:otherwise></xsl:otherwise>
												</xsl:choose></td>
									</xsl:if>
									<xsl:if test="$opdracht_qr_bookmark != ''">
										<td style="padding: 0px;">
											<xsl:element name="img">
											<xsl:attribute name="align">right</xsl:attribute>
											<xsl:attribute name="width">125px</xsl:attribute>
											<xsl:attribute name="src">https://<xsl:value-of select="/facilitor/header/custId"/>.facilitor.nl/?u=<xsl:value-of select="$opdracht_qr_bookmark"/>&amp;text=%3fmobile%3D1%26u%3Dopdracht%26k%3D<xsl:value-of select="key"/></xsl:attribute></xsl:element>
										</td>
									</xsl:if>
								</tr>
							</tbody>
						</table>
						<br/>
						<br/>
						<table border="0">
							<tbody>
								<tr>
									<td>Met vriendelijke groet,
										<br/>AAFM Facility Management B.V.</td>
								</tr>
								<tr>
									<td height="20"/>
								</tr>
							</tbody>
						</table>
						<table width="100%" border="0">
							<tbody>
								<tr>
									<td class="footer" width="100%">Deze brief is automatisch gegenereerd en daarom niet ondertekend.</td>
								</tr>
							</tbody>
						</table>
						<table width="100%" border="0">
							<tbody>
								<tr>
									<td class="footer" width="100%">Gelieve in alle correspondentie betreffende deze opdracht het ordernummer
										<xsl:value-of select="concat($customer_code, ' ', melding/discipline/srtdiscipline/prefix, melding/key, '/', bedrijfopdr_volgnr)"/> te vermelden.</td>
								</tr>
							</tbody>
						</table>
						<table width="100%" border="0">
							<tbody>
								<tr>
									<td class="footer" width="100%">Servicedesk
										<xsl:value-of select="$customer"/>
										<span class="seperator">|</span>T <xsl:call-template name="servicedesk_telefoon"></xsl:call-template>
										<span class="seperator">|</span>Postbus 80009
										<span class="seperator">|</span>5600 JZ Eindhoven
										<span class="seperator">|</span><xsl:call-template name="customer_email"></xsl:call-template></td>
								</tr>
							</tbody>
						</table>
					</xsl:element>
				</html>
			</xsl:otherwise>
		</xsl:choose>
	</xsl:template>
</xsl:stylesheet>
<!-- Stylesheet edited using Stylus Studio - (c) 2004-2007. Progress Software Corporation. All rights reserved. --><!-- Stylesheet edited using Stylus Studio - (c) 2004-2007. Progress Software Corporation. All rights reserved. -->