<%@language = "javascript" %>
<%
/*  $Revision$
    $Id$

    File:         alg_show_gebouw.asp
    Description:  show gebouw details
    Parameters:   bld_key


    Context:
    Note:

*/ %>
<!-- #include file="../Shared/common.inc" -->
<!-- #include file="../Shared/iface.inc" -->
<!-- #include file="../Shared/selector.inc" -->
<!-- #include file="../Shared/plaatsselector.inc" -->
<!-- #include file="../Shared/persoonselector.inc" -->
<!-- #include file="../API2/api2.inc" -->
<!-- #include file="alg_flexkenmerk.inc" -->
<!-- #include file="alg.inc" -->

<%
FCLTHeader.Requires({ plugins:["jQuery"],
                      js: [] })

var ins_score_enabled = S("ins_score_enabled") == 1;
var bld_key  = getQParamInt("bld_key");
var onrgoedlvl = "G";
var this_alg = alg.func_enabled(bld_key, onrgoedlvl);
user.auth_required_or_abort(this_alg.readman || this_alg.readuse);

var sql = " SELECT * "
        + "   FROM alg_gebouw "
        + "  WHERE alg_gebouw_key = " + bld_key;
var oRs = Oracle.Execute(sql);
var bld_srtkey  = oRs("alg_srtgebouw_key").Value;
var bld_naam    = oRs("alg_gebouw_naam").Value;
var bld_code    = oRs("alg_gebouw_code").Value;
var bld_descr   = oRs("alg_gebouw_omschrijving").Value;
var bld_adres    = oRs("alg_gebouw_adres").Value;
var bld_postcode = oRs("alg_gebouw_postcode").Value;
var bld_maak    = oRs("alg_gebouw_aanmaak").Value;
var bld_email   = oRs("alg_gebouw_email").Value;
var bld_image   = oRs("alg_gebouw_image").Value;
var bld_teken   = oRs("alg_gebouw_getekend").Value;
var bld_opp     = oRs("alg_gebouw_bruto_vloeropp").Value;
var bld_omtrek  = oRs("alg_gebouw_omtrek").Value;
var bld_inhoud  = oRs("alg_gebouw_inhoud").Value;
var bld_opmerk  = oRs("alg_gebouw_opmerking").Value;
var mld_adres   = oRs("mld_adres_key").Value;
var prs_kstpl   = oRs("prs_kostenplaats_key").Value;
var bld_ordrnr  = oRs("alg_gebouw_ordernr").Value;
var bld_dwgx    = oRs("alg_gebouw_dwgx").Value;
var bld_dwgy    = oRs("alg_gebouw_dwgy").Value;
var bld_x       = oRs("alg_gebouw_x").Value;
var bld_y       = oRs("alg_gebouw_y").Value;
var bld_bez     = oRs("alg_gebouw_bez").Value;
var bld_mld     = oRs("alg_gebouw_mld").Value;
var bld_deleted = oRs("alg_gebouw_verwijder").Value != null;
var bld_groep   = oRs("alg_gebouw_groep").Value;
var dienstniveau_key = oRs("mld_dienstniveau_key").Value;
var beginuur   = oRs("alg_gebouw_beginuur").Value;
var einduur    = oRs("alg_gebouw_einduur").Value;
var werkdagen  = oRs("alg_gebouw_werkdagen").Value;
var toon_telefoon  = oRs("alg_gebouw_toon_telefoon").Value;
var toon_email     = oRs("alg_gebouw_toon_email").Value;
var toon_kenteken  = oRs("alg_gebouw_toon_kenteken").Value;
var verantw    = oRs("prs_perslid_key_verantw").Value;
var verantw2    = oRs("prs_perslid_key_verantw2").Value;
var vervaldatum = oRs("alg_gebouw_vervaldatum").Value;
var geb_score1 = oRs("alg_gebouw_mjb_score1").Value;
var actie_grp_key = oRs("bez_actie_groep_key").Value;
var kalender_id = oRs("mld_vrije_dagen_id").Value;
oRs.Close();
%>

<html>
  <head>
<%  FCLTHeader.Generate(); %>
    <script  type="text/javascript" >
      function bld_change()
      {
        if (FcltMgr.startEdit(window))
          window.location.href = "alg_edit_gebouw.asp?bld_key=<%=bld_key%>"
      }
      function bld_delete()
      {
        FcltMgr.confirm(L("lcl_alg_del_txt_gebouw"), function() {
            var data = {
                key: <%=bld_key%>,
                level: "G"
            };
            <% protectRequest.dataToken("data"); %>
            $.post("alg_delete.asp",
                data,
                FcltCallbackClose,
                "json");
        });
      }
    </script>
  </head>

  <body class="showmode">
  <% SUBFRAME_START(); %>
<%  var buttons = [];


    if (!bld_deleted)
    {
      if (this_alg.writeman || this_alg.writeuse)
        buttons.push({title: L("lcl_change"), action:"bld_change()", icon: "fa-fclt-edit" });
    }
    if (!bld_deleted)
    {
      if (this_alg.writeman) // ALGMAN nodig
        buttons.push({title: L("lcl_delete"), action:"bld_delete()", icon: "fa-trash-alt" });
    }

    IFRAMER_HEADER(L("lcl_alg_gebouw_frame"), buttons);
    if (bld_deleted)
      {
        SIMPLE_BLOCK_START();
%>      <div class="alg_deleted"><%=L("lcl_record_is_deleted")%></div><%
        SIMPLE_BLOCK_END();
      }
      %><form name=u2 onSubmit="return false;">
<%      BLOCK_START("algLoc1", L("lcl_building"), {icon: "fa-building"});
        FCLTplaatsselector(-1,
                           { gebouwkey: bld_key,
                             startlevel: 2, //Locatie
                             eindlevel: 3, // Gebouw
                             moreinfo: true,  // wel beetje suf om door te linken naar jezelf
                             readonly: true
                           });
        ROFIELDTR("fld", L("lcl_estate_gebouw_man_code"), bld_code);
        sql = "SELECT alg_srtgebouw_key"
            + "     , " + lcl.xsqla('alg_srtgebouw_omschrijving', 'alg_srtgebouw_key')
            + "  FROM alg_srtgebouw"
            + " WHERE alg_srtgebouw_verwijder IS NULL"
            + " ORDER BY alg_srtgebouw_upper"
        FCLTselector("bld_srtkey",
                     sql,
                     { label: L("lcl_estate_gebouw_srtgebouw"),
                       initKey: bld_srtkey,
                       emptyOption: "",
                       suppressEmpty: true,
                       readonly: true
                     });
        ROFIELDTR("fld", L("lcl_estate_gebouw_man_descr"),    bld_descr, {suppressEmpty:true});
        ROFIELDTR("fld", L("lcl_estate_gebouw_man_adres"),    bld_adres, {suppressEmpty:true});
        ROFIELDTR("fld", L("lcl_estate_gebouw_man_postcode"), bld_postcode, {suppressEmpty:true});
        ROFIELDTR("fld", L("lcl_estate_gebouw_man_opmerk"),   bld_opmerk, {suppressEmpty:true});
        ROFIELDTR("fld", L("lcl_estate_gebouw_groepkenmerk"), bld_groep, {suppressEmpty:true});

        sql = "SELECT prs_kostenplaats_key"
            + "     , k.prs_kostenplaats_nr || ' ' || k.prs_kostenplaats_omschrijving"
            + "  FROM prs_kostenplaats k"
            + " WHERE k.prs_kostenplaats_module = 'ALG'"
            + " ORDER BY prs_kostenplaats_upper";

    BLOCK_END();

    BLOCK_START("algLoc2", L("lcl_alg_gebouw_fysiek"), {icon: "fa-ruler-combined"});
        var calcopp = alg.calc_algm2(bld_key, onrgoedlvl);
        ROFIELDTR("fld", L("lcl_estate_gebouw_floors_vloeropp") + L("lcl_estate_calc_vloeropp"), calcopp.oppfloors, {suppressEmpty: true, datatype: "float"});
        ROFIELDTR("fld", L("lcl_estate_ruimte_bruto_vloeropp") + L("lcl_estate_calc_vloeropp"), calcopp.opprooms, {suppressEmpty: true, datatype: "float"});
        ROFIELDTR("fld", L("lcl_estate_ruimte_opp_alt1") + L("lcl_estate_calc_vloeropp"), calcopp.oppalt1, {suppressEmpty: true, datatype: "float"});
        ROFIELDTR("fld", L("lcl_estate_ruimte_opp_alt2") + L("lcl_estate_calc_vloeropp"), calcopp.oppalt2, {suppressEmpty: true, datatype: "float"});

        ROFIELDTR("fld", L("lcl_estate_gebouw_man_bruto_vloeropp"), bld_opp, {suppressEmpty: true, datatype: "float"});
        ROFIELDTR("fld", L("lcl_estate_gebouw_man_omtrek"), bld_omtrek, {suppressEmpty: true, datatype: "float"});
        ROFIELDTR("fld", L("lcl_estate_gebouw_man_inhoud"), bld_inhoud, {suppressEmpty: true, datatype: "float"});
        ROFIELDTR("fld", L("lcl_geoxcoord"), bld_x, {suppressEmpty:true});
        ROFIELDTR("fld", L("lcl_geoycoord"), bld_y, {suppressEmpty:true});
        ROFIELDTR("fld", L("lcl_alg_gebouw_mjb_score1"), geb_score1, {suppressEmpty: true});
    BLOCK_END();

    // suppressempty explicits
    if (!(prs_kstpl==null && bld_ordrnr == null && verantw==null && verantw2 == null && bld_email == null && bld_image == null && vervaldatum == null))
    {
        BLOCK_START("algLoc3", L("lcl_alg_gebouw_administr"), {icon: "fa-clipboard"});
        var fldcls = "fld";
        if (vervaldatum <= new Date())
            fldcls += " expired2";
        ROFIELDTR(fldcls, L("lcl_alg_vervaldatum"), toDateString(vervaldatum), {suppressEmpty: true});
            FCLTselector("prs_kstpl",
                         sql,
                         { label: L("lcl_prs_dept_kosten"),
                           initKey: prs_kstpl,
                           emptyOption: "",
                           suppressEmpty: true,
                           readonly: true
                         });
            ROFIELDTR("fld", L("lcl_estate_gebouw_ordernr"), bld_ordrnr, {suppressEmpty:true});
            FCLTpersoonselector("verantw",
                                "sgVerantw",
                                { perslidKey: verantw,
                                  label: L("lcl_alg_verantw"),
                                  readonly: true,
                                  suppressEmpty: true,
                                  moreinfo: this_alg.readman
                                });
            FCLTpersoonselector("verantw2",
                                "sgVerantw2",
                                { perslidKey: verantw2,
                                  label: L("lcl_alg_verantw2"),
                                  readonly: true,
                                  suppressEmpty: true,
                                  moreinfo: this_alg.readman
                                });

            ROFIELDTR("fld", L("lcl_alg_gebouw_email"), bld_email, { suppressEmpty: true, type: "email" });
            FILEPICKERTR("bld_image", L("lcl_alg_gebouw_image"), bld_image, { "key": bld_key, "module": "ALGPHG", "readonly": true });
        BLOCK_END();
    }
    if (!(dienstniveau_key == null && mld_adres == null && beginuur == null && einduur == null && werkdagen == 0))
    {
        BLOCK_START("algLoc4", L("lcl_alg_gebouw_facilitair"), {icon: "fa-users-cog"});

            if (dienstniveau_key)
            {
              sql = "SELECT mld_dienstniveau_key"
                  + "     , " + lcl.xsqla("mld_dienstniveau_omschr", "mld_dienstniveau_key")
                  + "  FROM mld_dienstniveau"
                  + " WHERE mld_dienstniveau_key = " + dienstniveau_key;
              oRs = Oracle.Execute(sql);
              ROFIELDTR("fld", L("lcl_mld_dienst_niveau"), oRs("mld_dienstniveau_omschr").value);
              oRs.Close();
            }

            sql = "SELECT mld_adres_naam"
                + "  FROM mld_adres"
                + " WHERE mld_adres_key = " + mld_adres;
            oRs = Oracle.Execute(sql);
            if (!oRs.eof)
            {
                ROFIELDTR("fld", L("lcl_delivery_address"), oRs("mld_adres_naam").value, {suppressEmpty: true});
            }
            oRs.Close();

            ROFIELDTR("fld", L("lcl_calendar"), kalender_id, {suppressEmpty: true});
            ROFIELDTR("fld", L("lcl_estate_gebouw_beginuur"), toTimeString(beginuur), {suppressEmpty:true} );
            ROFIELDTR("fld", L("lcl_estate_gebouw_einduur"), toTimeString(einduur), {suppressEmpty:true} );
            ROCHECKBOXTR("fldalgwerk", L("lcl_estate_gebouw_werkdagen"), werkdagen==1);
            ROCHECKBOXTR("fldalgmld", L("lcl_estate_gebouw_mld"), bld_mld==1);
        BLOCK_END();
    }

    if (user.checkAutorisation("WEB_BEZMGT", true) && bld_bez==1)
    {
        BLOCK_START("algLoc5", L("lcl_alg_gebouw_bezoek"), {icon: "fa-user-tag"});

          ROCHECKBOXTR("fldalgbez", L("lcl_estate_gebouw_bez"), bld_bez==1);
          var sql = api2.splitLOV2sql(L("lcl_estate_gebouw_toontelfLOV"));
          FCLTselector("toon_telefoon",
                       sql,
                       { label: L("lcl_estate_gebouw_toon_telefoon"),
                         initKey: toon_telefoon,
                         readonly: true,
                         suppressEmpty: true,
                         extraclass: "notmulti"
                       });
          sql = api2.splitLOV2sql(L("lcl_estate_gebouw_toonmailLOV"));
          FCLTselector("toon_email",
                      sql,
                      { label: L("lcl_estate_gebouw_toon_email"),
                        initKey: toon_email,
                        readonly: true,
                        suppressEmpty: true,
                        extraclass: "notmulti"
                      });
          sql = api2.splitLOV2sql(L("lcl_estate_gebouw_toonkentLOV"));
          FCLTselector("toon_kenteken",
                      sql,
                      { label: L("lcl_estate_gebouw_toon_kenteken"),
                        initKey: toon_kenteken,
                        readonly: true,
                        suppressEmpty: true,
                        extraclass: "notmulti"
                      });
            var sql = "SELECT bez_actie_groep_omschrijving"
                    + "  FROM bez_actie_groep"
                    + " WHERE bez_actie_groep_key = "+ actie_grp_key;
            var oRs = Oracle.Execute(sql);
            if (!oRs.eof) {
                ROFIELDTR("fld", L("bez_actie_groep"), oRs("bez_actie_groep_omschrijving").Value);
            }
            oRs.Close();
          BLOCK_END();
    }

    generateFlexKenmerkBlock ({ onrgoed_key    : bld_key,
                                onrgoed_niveau : onrgoedlvl,
                                reado          : true,
                                this_alg       : this_alg
                              });
%>
      </form>
    <% SUBFRAME_END(); %>
  </body>
</html>
<% ASPPAGE_END(); %>
